自己写工具校验MD5

DrZhang

很多软件作者会提供MD5值，以防发布的内容被其他人修改，导致用户中毒或信息泄露等情况出现。
我们倡导能小则小，能不用外来软件就不用外来软件，让电脑保持干净、整洁！让生活充满秩序！
工具已经更新在【https://wp.me/p80aHo-1e3】

自制MD5校验脚本<2K

利用Windows自带的CMD程序进行校验。

打开记事本，将下面的代码复制进去，然后保存为"md5.bat"，保存的时候需要双引号，然后把这个文件放在需要校验的文件相同目录下，运行。然后选择要计算文件的编号即可。

@echo off
setlocal enabledelayedexpansion
chcp 65001 >nul
title MD5/SHA256计算工具
echo 张敖制作 https://datahold.cn
echo 把本软件放在测试文件相同的目录下运行
echo 更新 2024年2月16日

:: 初始化变量
set /a count=1

:: 列出当前目录下所有文件，并给它们编号
echo Available files:
for %%f in (*) do (
    echo !count! - %%f
    set "file!count!=%%f"
    set /a count+=1
)

:: 获取用户输入
set /p choice="Select a file number: "
if "!choice!"=="" goto eof

:: 通过编号获取文件名
set "selectedFile=!file%choice%!"

:: 检查用户是否选择了有效编号
if "!selectedFile!"=="" (
    echo Invalid selection.
    goto eof
)

:: 使用CertUtil计算所选文件的MD5哈希值，并只显示MD5哈希值
echo Calculating MD5 and SHA256 for "!selectedFile!"...
for /f "tokens=* skip=1" %%a in ('CertUtil -hashfile "!selectedFile!" MD5') do (
    set "md5hash=%%a"
    goto displayMD5
)

:displayMD5
echo MD5: !md5hash!

:: 使用CertUtil计算所选文件的SHA256哈希值，并只显示SHA256哈希值
for /f "tokens=* skip=1" %%a in ('CertUtil -hashfile "!selectedFile!" SHA256') do (
    set "sha256hash=%%a"
    goto displaySHA256
)

:displaySHA256
echo SHA256: !sha256hash!

:eof
endlocal

echo 按任意键退出/Press any key to exit.
pause >nul

DrZhang

检测一下自己的md5，看看和我的一样不一样
名称：MD5.zip
大小：1 KB
MD5：becdc41ed373485d92f575a615c8d9e0
SHA256：e38af4a446456837f4a9c4d7b83d7ce6a2671e0ce14ac48f149faed74f290bc7